Vsebina

# Funkcija CreateUnoServiceWithArguments

Tvori instanco storitve UNO z upraviteljem procesnih storitev ProcessServiceManager, vključno z dopolnilnimi neobveznimi argumenti.

### Skladnja:

        CreateUnoServiceWithArguments(ServiceName As String, Arguments() As Variant) As Object

Storitve UNO, ki jih je mogoče uporabiti s funkcijo CreateUnoServiceWithArguments, je mogoče identificirati z imeni metod, ki sledijo vzorcu createInstanceWith.. ali createWith...

### Vrnjena vrsta:

Predmet

Seznam storitev, ki so na razpolago, najdete na strani com::sun::star Module (v angl. jeziku).

### Parametri:

Ime | Vrsta | Opis
--- | --- | ---
imeStoritve | String | Ime storitve UNO, ki naj bo ustvarjena.
Argumenti | Variant | Eden ali več argumentov, ki določajo instanco storitve. Argumenti so shranjeni kot enodimenzionalno polje, skladno s položaji elementov v definiciji metode konstruktorja.

### Primer:

Spodnji primer com.sun.star.ui.dialogs.FilePicker prikaže pogovorno okno Shrani kot LibreOffice z dvema dodatnima kontrolnikoma: s seznamskim in potrditvenim poljem.

        Sub FileSaveAsDialog()
           td = com.sun.star.ui.dialogs.TemplateDescription
           options = td.FILESAVE_AUTOEXTENSION_TEMPLATE
           dlg = CreateUnoServiceWithArguments( _
              "com.sun.star.ui.dialogs.FilePicker", _
              Array(options))
           dlg.execute()
        End Sub ' FileSaveAsDialog

Pogovorna okna za odpiranje datotek, kot npr. Odpri, Shrani kot, Vstavi besedilo in podobna, so na voljo na dva načina:

- kot domorodni izbirniki datotek upravitelja oken vašega operacijskega sistema;

- kot vgrajena pogovorna okna izbirnika datotek LibreOffice.

Uporabite LibreOffice – NastavitveOrodja – Možnosti – LibreOffice – Splošno, da preklopite med obema možnostma.

Storitve UNO imajo obsežno spletno dokumentacijo na spletišču api.libreoffice.org. Obiščite stran o storitvi FilePicker (v angl.), da izveste več o metodah, ki jih nudi storitev, uporabljena v zgornjem primeru.

### Primer:

Naslednja koda uporablja storitev com.sun.star.security.DocumentDigitalSignatures za podpisovanje trenutnega dokumenta:

    Sub  SignCurrentDocDialog
       Dim pv(0) as new com.sun.star.beans.PropertyValue
       pv(0).Name  = "StorageFormat"
       pv(0).Value = "ZipFormat"
       mode = com.sun.star.embed.ElementModes
       sf = CreateUnoService("com.sun.star.embed.StorageFactory")
       storage = sf.createInstanceWithArguments(Array(ThisComponent.URL, mode.WRITE, pv))
       dds = CreateUnoServiceWithArguments( _
          "com.sun.star.security.DocumentDigitalSignatures", _
          Array("1.2", True))
       dds.signDocumentContent(storage, Null)
    End Sub ' SignCurrentDocDialog

Metodi konstruktorja CreateWithVersion in createWithVersionAndValidSignature constructor methods v storitvi UNO com.sun.star.security.DocumentDigitalSignatures nakazujeta dva različna načina tvorjenja instance te storitve s funkcijo CreateUnoServiceWithArguments.

Podobne teme

Funkcija CreateUnoService

Predmeti, funkcije in storitve UNO Basic

Raba funkcij programa Calc v makrih

Podprite nas!