Vsebina

# Funkcija CreateUnoService

Tvori instanco storitve UNO z upraviteljem procesnih storitev ProcessServiceManager.

### Skladnja:

         CreateUnoService(serviceName As String) As Object

### Vrnjena vrsta:

Predmet

### Parametri:

Ime | Vrsta | Opis
--- | --- | ---
imeStoritve | String | Ime storitve. Seznam storitev, ki so na razpolago, najdete na strani com::sun::star Module (v angl. jeziku).

### Primer:

Spodnji primer ustvari funkcijo FileExists, ki uporablja storitev com.sun.star.ucb.SimpleFileAccess, da preizkusi, če dana pot predstavlja obstoječo datoteko.

        Function FileExists(sPath as String) As Boolean
            Dim svcSFA As Object
            Set svcSFA = CreateUnoService("com.sun.star.ucb.SimpleFileAccess")
            Dim bExists As Boolean : bExists = svcSFA.exists(sPath)
            Dim bIsFolder As Boolean : bIsFolder = svcSFA.IsFolder(sPath)
            FileExists = bExists And Not bIsFolder
        End Function ' FileExists

Storitve UNO imajo obsežno spletno dokumentacijo na spletišču api.libreoffice.org. Obiščite stran o storitvi SimpleFileAccess (v angl.), da izveste več o metodah, ki jih nudi storitev, uporabljena v zgornjem primeru.

### Primer:

Naslednja koda uporablja storitev com.sun.star.ui.dialogs.FilePicker, da odpre pogovorno okno za odprtje datoteke:

    Sub Main
       fName = FileOpenDialog ("Izberite datoteko")
       Print "izbrana datoteka: "+fName
    End Sub

    Function FileOpenDialog(title As String) As String
       res = com.sun.star.ui.dialogs.ExecutableDialogResults
       filepicker = CreateUnoService("com.sun.star.ui.dialogs.FilePicker")
       With filepicker
          .Title = title
          .MultiSelectionMode = True
          .appendFilter("Calc docs","*.ods;*.csv;*.123")
          .appendFilter("Writer or Base docs","*.odt;*.odb")
          .appendFilter("All files","*.*")
           If res.OK = .execute() Then
              files = .getSelectedFiles()
              FileOpenDialog=files(0)
           EndIf
       End With
    End Function ' FileOpenDialog

Podobne teme

Funkcija CreateUnoServiceWithArguments

Predmeti, funkcije in storitve UNO Basic

Raba funkcij programa Calc v makrih

Podprite nas!