Funkcja AGREGUJ

Spis treści

# AGREGUJ function

Zwraca wyniki agregacji obliczeń w zakresie. Dostępne są różne funkcje agregacji z listy poniżej. Funkcja agregacji pozwala pominąć ukryte wiersze, błędy SUMY.CZĘŚCIOWE i inne wyniki funkcji AGREGUJ w obliczeniach.

Funkcja AGREGUJ jest stosowana do pionowych zakresów danych wraz z aktywowanym autofiltrem. Jeśli autofiltr nie jest aktywowany, automatyczne przeliczanie wyniku funkcji nie działa dla nowo ukrytych wierszy. Nie jest przewidziane, aby funkcja ta działała z poziomymi zakresami, jednakże może być stosowana z pewnymi ograniczeniami. W szczególności funkcja AGREGUJ stosowana do poziomych zakresów danych nie rozpoznaje ukrytych kolumn, jednakże poprawnie pomija błędy i wyniki SUMY.CZĘŚCIOWE i innych funkcji AGREGUJ osadzonych w rzędzie.

### Składnia

AGREGUJ(funkcja; opcja; liczba 1 [; liczba 2] [; ...; [liczba 253]])

lub

AGREGUJ(funkcja; opcja; tablica[; k])

Funkcja – argument obligatoryjny. Indeks funkcji A lub odwołanie do komórki z wartością od 1 do 19, w zgodzie z następującą tabelą:

Indeks funkcji | Zastosowana opcja
--- | ---
1 | ŚREDNIA
2 | LICZBA
3 | NIEPUSTE
4 | MAKS.
5 | MIN.
6 | ILOCZYN
7 | ODCH.STANDARD.PRÓBKI
8 | ODCH.STAND.POPUL
9 | SUMA
10 | WARIANCJA.PRÓBKI
11 | WARIANCJA.POP
12 | MEDIANA
13 | WYST.NAJCZĘŚCIEJ.WART
14 | MAKS.K
15 | MIN.K
16 | PERCENTYL.PRZEDZ.ZAMK
17 | KWARTYL.PRZEDZ.ZAMK
18 | PERCENTYL.PRZEDZ.OTW
19 | KWARTYL.PRZEDZ.OTW

Opcja – argument obligatoryjny. Indeks opcji lub odwołanie do komórki z wartością od 0 do 7 determinuje co należy zignorować w zakresie dla funkcji.

Indeks opcji | Zastosowana opcja
--- | ---
0 | Ignoruj tylko zagnieżdżone funkcje SUMY.CZĘŚCIOWE i AGREGUJ
1 | Ignoruj tylko ukryte wiersze, zagnieżdżone funkcje SUMY.CZĘŚCIOWE i AGREGUJ
2 | Ignoruj tylko błędy, zagnieżdżone funkcje SUMY.CZĘŚCIOWE i AGREGUJ
3 | Ignoruj ukryte wiersze, błędy, zagnieżdżone funkcje SUMY.CZĘŚCIOWE i AGREGUJ
4 | Niczego nie ignoruj
5 | Ignoruj tylko ukryte wiersze
6 | Ignoruj tylko błędy
7 | Ignoruj tylko ukryte wiersze i błędy

Liczba1 – wymagany argument. Pierwszy argument liczbowy (jeśli zakres jest ustawiony przez listę wartości wewnątrz funkcji) lub odwołanie do komórki, która go zawiera.

Liczba2, 3, ... – opcjonalnie. Argument liczbowy lub odwołanie do komórki (do 253 argumentów), dla której potrzebna jest wartość zagregowana.

Tablica – wymagany argument. Tablicę można określić poprzez granice zakresu, nazwę nazwanego zakresu lub etykietę kolumny.

Aby użyć etykiet kolumn, funkcja "Automatycznie znajdź etykiety kolumn i wierszy" musi być włączona.

k – wymagany argument dla funkcji: MAKS.K, SMALL, PERCENTYL.PRZEDZ.ZAMK, KWARTYL.PRZEDZ.ZAMK, PERCENTYL.PRZEDZ.OTW, KWARTYL.PRZEDZ.OTW. Jest to argument liczbowy, który musi odpowiadać drugiemu argumentowi tych funkcji.

### Przykłady

| A | B | C
1 | KolumnaJeden | KolumnaDwa | KolumnaTrzy
2 | 34 | 11 | 12
3 | 10 | 56 | 35
4 | #DZIEL/0! | 5 | 3
5 | 20 | 8 | 1
6 | 0 | 8 | 9
7 | #ARG! | 20 | 21
8 | 5 | 7 | 8
9 | 14 | 0 | 5

=AGREGUJ(4;2;A2:A9)
Zwraca maksymalną wartość dla zakresu A2:A9 = 34.

=AGREGUJ(9;5;A5:C5)
Zwraca sumę dla zakresu A5:C5 = 29, nawet jeśli część kolumn jest ukrytych.

=AGREGUJ(9;5;B2:B9)
Zwraca sumę kolumny B = 115. Jeśli jakiś wiersz jest ukryty, funkcja pomija jego wartość. Na przykład: jeśli siódmy wiersz jest ukryty, funkcja zwraca 95.

Jeśli potrzebujesz zastosować funkcję z zakresem 3D, poniższy przykład pokazuje jak to zrobić.

=AGREGUJ(13;3;Arkusz1.B2:B9:Arkusz3.B2:B9)
Funkcja zwraca tryb wartości drugiej kolumny przez arkusze 1:3 (zawierające te same dane) = 8.

Możesz użyć w formule odwołań do komórki lub do zakresu dla każdego argumentu. Następujący przykład pokazuje, jak to działa. Ponadto pokazuje, jak użyć etykiet kolumn do określenia macierzy.

=AGREGUJ(E3;E5;'KolumnaJeden')
Jeśli E3 = 13 i E5 = 7, funkcja zwraca tryb pierwszej kolumny = 10.

#### Szczegóły techniczne

Ta funkcja jest dostępna od wersji 4.4 LibreOffice.

Ta funkcja NIE jest częścią standardu Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format. Przestrzeń nazw to

COM.MICROSOFT.AGGREGATE

Tematy pokrewne

Strona wiki AGREGUJ.

ŚREDNIA, LICZBA, NIEPUSTE, MAKS, MIN, ILOCZYN, ODCH.STANDARD.PRÓBKI, ODCH.STAND.POPUL, SUMA, WARIANCJA.PRÓBKI, WARIANCJA.POP, MEDIANA, WYST.NAJCZĘŚCIEJ.WART, MAKS.K, MIN.K, PERCENTYL.PRZEDZ.ZAMK, KWARTYL.PRZEDZ.ZAMK, PERCENTYL.PRZEDZ.OTW, KWARTYL.PRZEDZ.OTW

Automatycznie znajdź etykiety kolumn i wierszy

Prosimy o wsparcie!