Inhoud

# GEMIDDELDE.ALS

Geeft het rekenkundig gemiddelde van alle cellen in een bereik die aan een bepaalde voorwaarde voldoen. De functie GEMIDDELDE.ALS telt alle resultaten op die overeenkomen met de logische test en deelt dit totaal door het aantal geselecteerde waardes.

Deze functie is beschikbaar sinds LibreOffice 4.0.

### Syntaxis

GEMIDDELDE.ALS(Bereik; Criterium; Gemiddeld bereik (optioneel))

Bereik – vereist argument. Een matrix, een naam van een benoemd bereik of een label van een kolom of een rij met getallen voor het bepalen van een gemiddelde of getallen of tekst voor de voorwaarde.

Criterium: Een criterium is een tekstuele expressie die is berekend op basis van een enkele celreferentie, formule, getal of tekst. Het wordt gebruikt in vergelijkingen met celinhoud.

Een verwijzing naar een lege cel wordt geïnterpreteerd als de numerieke waarde 0.

Een overeenkomende uitdrukking kan zijn:

- Een getal of logische waarde. Een overeenkomende celinhoud is gelijk aan het getal of de logische waarde.

- Een waarde die begint met een vergelijker (, <=, =, >, >=, <>).

  Voor =: als de waarde leeg is, komt deze overeen met lege cellen.

  Voor <> geldt dat als de waarde leeg is, deze overeenkomt met niet-lege cellen.

  Als de waarde voor <> niet leeg is, komt deze overeen met alle celinhoud behalve de waarde, inclusief lege cellen.

  Opmerking: "=0" komt niet overeen met lege cellen.

  Voor = en <>, als de waarde niet leeg is en niet kan worden geïnterpreteerd als een getaltype of één van de subtypen ervan en de eigenschap Zoekcriteria = en <> moeten op hele cellen toepasbaar zijn is aangevinkt, de vergelijking vindt plaats met de volledige celinhoud, als niet aangevinkt, wordt er vergeleken met elk subgedeelte van het veld dat aan de criteria voldoet. Voor = en <>, als de waarde niet leeg is en niet kan worden geïnterpreteerd als een getaltype of als één van de subtypes ervan van toepassing is.

- Andere tekstwaarde. Als de eigenschap Zoekcriteria = en <> moeten op hele cellen toepasbaar zijn waar is , is de vergelijking met de gehele celinhoud. Als deze niet waar is, wordt er met elk subdeel van het veld vergeleken dat aan de criteria voldoet. De expressie kan tekst, getallen, reguliere expressies of jokertekens bevatten (indien ingeschakeld in berekeningsopties).

De zoekopdracht ondersteunt jokertekens of reguliere expressies. Als reguliere expressies zijn ingeschakeld, kunt u "all.*" invoeren, bijvoorbeeld om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere expressie is, moet u elk metateken of operator van een reguliere expressie laten voorafgaan door een "\"-teken, of de tekst in \Q...\E insluiten. U kunt de automatische evaluatie van jokertekens of reguliere expressies in- en uitschakelen in LibreOffice - VoorkeurenExtra - Opties - LibreOffice Calc - dialoogvenster Berekenen .

Wanneer u functies gebruikt waarbij één of meer argumenten tekenreeksen voor zoekcriteria zijn, die een reguliere expressie vertegenwoordigen, is de eerste poging om de tekenreekscriteria om te zetten naar getallen. ".0" wordt bijvoorbeeld omgezet naar 0,0 enzovoort. Als dit lukt, is de overeenkomst geen overeenkomst met een reguliere expressie, maar een numerieke overeenkomst. Als u echter overschakelt naar een taalinstelling waar het decimaalteken niet de punt is, werkt de conversie van reguliere expressies. Om de uitvoering van de reguliere expressie af te dwingen in plaats van een numerieke expressie, gebruikt u een expressie die niet verkeerd kan worden gelezen als numeriek, zoals ". [0]" of ". \ 0" of "(? I) .0".

Gemiddeld bereik (optioneel). Het is een reeks waardes voor de berekening van het gemiddelde.

Als het Gemiddeld bereik niet is opgegeven, wordt Bereik gebruikt voor beide, de berekening van het gemiddelde en de zoekopdracht volgens de voorwaarde. Als het Gemiddeld bereik is is gespecificeerd, wordt het Bereik alleen gebruikt voor de voorwaardetest, terwijl Gemiddeld bereik wordt gebruikt voor de gemiddelde berekening.

Als een cel in een bereik van waardes voor het berekenen van het gemiddelde leeg is of tekst bevat, negeert de functie GEMIDDELDE.ALS deze cel.
Als de hele reeks leeg is, alleen tekst bevat of alle waardes van de reeks voldoen niet aan de voorwaarde (of een combinatie hiervan), geeft de functie de fout #DELING.DOOR.0!.

### Voorbeelden

Overweeg de volgende tabel

| A | B | C
1 | Productnaam | Sales | Revenue
2 | penhouder | 20 | 65
3 | pen | 35 | 85
4 | kladblok | 20 | 190
5 | boek | 17 | 180
6 | etui | niet | niet

In alle onderstaande voorbeelden, bevatten bereiken voor berekening de rij # 6, die genegeerd wordt omdat deze tekst bevat.

#### Eenvoudig gebruik

=GEMIDDELDE.ALS(B2:B6;"<35")

Berekent het gemiddelde van de waardes van het bereik B2:B6 dat er minder dan 35 zijn. Dit geeft 19, omdat de tweede rij niet deelneemt in de berekening.

=GEMIDDELDE.ALS(B2:B6;"<"&MAX(B2:B6))

Berekent het gemiddelde van waardes van hetzelfde bereik, dat kleiner is dan de maximale waarde van dit bereik. Geeft 19, omdat de grootste waarde (tweede rij) niet deelneemt aan de berekening.

=GEMIDDELDE.ALS(B2:B6;">"&KLEINSTE(B2:B6;1))

Berekent het gemiddelde van waardes van hetzelfde bereik, dat groter is dan de kleinste waarde van dit bereik. Geeft 25, omdat de kleinste waarde (vierde rij) niet deelneemt aan de berekening.

#### Gebruik het Gemiddelde bereik

=GEMIDDELDE.ALS(B2:B6;"<35";C2:C6)

De functie zoekt uit welke waardes minder dan 35 zijn in het bereik B2:B6 en berekent het gemiddelde van corresponderende waardes van het bereik C2:C6. Geeft 145, omdat de tweede rij niet deelneemt in de berekening.

=GEMIDDELDE.ALS(B2:B6;">"&MIN(B2:B6);C2:C6)

De functie zoekt uit welke waardes uit het bereik B2:B6 groter zijn dan de kleinste waarde in het bereik B2:B6 en berekent het gemiddelde van corresponderende waardes in het bereik C2:C6. Geeft 113,3, omdat de vierde rij (waar de minste waarde in het bereik B2: B6 in staat) niet deelneemt aan de berekening.

=GEMIDDELDE.ALS(B2:B6;"<"&GROOTSTE(B2:B6;2);C2:C6)

De functie zoekt uit welke waardes uit het bereik B2:B6 kleiner zijn dan de tweede grote waarde in het bereik B2:B6 en berekent het gemiddelde van corresponderende waardes in het bereik C2: C6. Geeft 180, omdat alleen de vierde rij deelneemt in de berekening.

#### Reguliere expressies gebruiken

=GEMIDDELDE.ALS(A2:A6;"pen";B2:B6)

De functie zoekt uit welke cellen van het bereik A2:A6 alleen het woord "pen" bevatten en berekent het gemiddelde van de overeenkomstige waardes uit het bereik B2:B6. Dit geeft 35, omdat alleen de tweede rij aan de berekening deelneemt. De zoekopdracht wordt uitgevoerd in het bereik A2:A6, maar de waardes worden berekend van het bereik B2:B6.

=GEMIDDELDE.ALS(A2:A6;"pen.*";B2:B6)

De functie zoekt uit welke van de cellen van het bereik A2:A6 die beginnen met "pen", eindigen met elke hoeveelheid andere symbolen en berekent het gemiddelde van de overeenkomstige waardes uit het bereik B2:B6. Dit geeft 27,5, want ook "pencil" voldoet nu aan de voorwaarde en zowel de eerste en tweede rij nemen deel aan de berekening.

=GEMIDDELDE.ALS(A2:A6;".*boek.*";B2:B6)

De functie zoekt uit welke van de cellen van het bereik A2: A6 die "boek" bevatten, beginnen en eindigend met elke hoeveelheid van andere symbolen en berekent het gemiddelde van de overeenkomstige waardes van het bereik B2:B6. Dit geeft 17, omdat alleen de vierde rij deelneemt aan de berekening.

#### Refereer naar een cel als een criterium

Als u een criterium gemakkelijk moet kunnen veranderen, kunt u deze in een aparte cel opvoeren en gebruik maken van een verwijzing naar deze cel in de voorwaarde van de GEMIDDELDE.ALS-functie.

=GEMIDDELDE.ALS(A2:A6;".*"&E2&".*";B2:B6)

De functie zoekt uit welke van de cellen van het bereik A2:A6 een combinatie van symbolen bevat die wordt aangegeven in E2, beginnend en eindigend met elke hoeveelheid van andere symbolen en berekent het gemiddelde van de overeenkomstige waardes van het bereik B2:B. Als E2 = boek, geeft de functie 17 terug.

=GEMIDDELDE.ALS(B2:B6;"<"&E2;C2:C6)

De functie zoekt uit welke van de cellen van het bereik A2:A6 kleiner zijn dan de waardes in E2 en berekent het gemiddelde van de overeenkomstige waardes uit het bereik B2:B6. Als E2 = 35, geeft de functie 145 terug.

#### Technische informatie

Deze functie maakt deel uit van het Open Document Format voor Office Applications (OpenDocument) standaard versie 1.2. (ISO/IEC 26300: 2-2015)

Verwante onderwerpen

Wiki-pagina GEMIDDELDE.ALS.

GEMIDDELDE, GEMIDDELDEA, GEM.DEVIATIE

AANTALLEN.ALS, MIN.ALS.VOORWAARDEN, MAX.ALS.VOORWAARDEN, GEMIDDELDEN.ALS, SOMMEN.ALS

Lijst met reguliere expressies

Help ons, alstublieft!