Funciones de bases de datos

Contenido

# Funciones de base de datos

### Información general

Las doce funciones de la categoría Base de datos le ayudan a analizar una base de datos sencilla que ocupa un área rectangular en una hoja de cálculo, compuesta de columnas y de filas, con los registros individuales organizados en filas. La celda de cabecera de cada columna muestra el nombre de esta y este nombre normalmente refleja el contenido de cada celda de esa columna en particular.

Las funciones de la categoría Base de datos aceptan estos tres argumentos:

1. BaseDeDatos. El intervalo de celdas de la base de datos.

2. CampoDeBaseDeDatos. La columna que contiene los datos que se utilizarán en los cálculos de la función.

3. CriteriosDeBúsqueda. El intervalo de celdas de un área separada de la hoja de cálculo que contiene los criterios de búsqueda.

Estos argumentos se describen a detalle más abajo.

Todas las funciones tienen el mismo concepto de funcionamiento. El primer paso lógico es utilizar el Criterio de Búsqueda para identificar el subconjunto de registros en la Base de datosque se utilizarán en los cálculos posteriores. El segundo paso consiste en extraer los valores de los datos y realizar los cálculos asociados a la función específica (media, suma, producto, etc.). Los valores que se procesan son los que están en el Campo de base de datos de los registros seleccionados.

Calc trata los datos y los valores lógicos (VERDADERO y FALSO) como numéricos al calcular con estas funciones.

### Argumentos de las funciones de base de datos

Las definiciones de argumentos siguientes se aplican a todas las funciones de la categoría Base de datos:

1. Argumento Base de datos

   BaseDeDatos indica el intervalo de celdas ocupado por la tabla de la base de datos. La primera fila del intervalo contiene los nombres de los campos e las filas posteriores son registros con sus valores de campo correspondentes.

   Una forma de definir el intervalo de celdas es ingresar la referencia de celda para la celda superior izquierda, seguida de dos puntos (:), y luego la referencia de celda inferior derecha. Un ejemplo podría ser A1:E10.

   El argumento Base de datos también se puede especificar pasando el nombre de un intervalo con nombre o intervalo de base de datos. El uso de un nombre expresivo para definir el intervalo de celdas puede mejorar la comprensibilidad de la fórmula y el mantenimiento del documento. Si el nombre no coincide con el nombre de un intervalo definido, Calc emite un error #¿NOMBRE?

   Otros errores que se pueden devolver como resultado de un argumento no válido en BaseDeDatos son #¡VALOR! y Err:504 (error en la lista de parámetros).

2. Argumento CampoDeBaseDeDatos

   CampoDeBaseDeDatos especifica la columna que la función utilizará para sus cálculos después de que se hayan aplicado los criterios de búsqueda y se hayan seleccionado las filas de datos. No está relacionado con los criterios de búsqueda.

   Especifique el argumento CampoDeBaseDeDatos de cualquiera de las siguientes maneras:

   - Al introducir una referencia a una celda de cabecera dentro del área Base de datos Alternativamente, si la celda ha recibido un nombre representativo como intervalo con nombre o intervalo de base de datos, introduzca ese nombre. Si el nombre no coincide con el nombre de un intervalo definido, Calc emite el error #¿NOMBRE? Si el nombre es válido pero no corresponde a una sola celda, Calc emite el Err:504 (error en la lista de parámetros).

   - Ingresando un número para especificar la columna en el área Base de datos, comenzando con 1. Por ejemplo, si una Base de datos ocupaba el intervalo de celdas D6: H123, ingrese 3 para indicar la celda de encabezado en F6. Calc espera un valor entero que se encuentre entre 1 y el número de columnas definido en Base de datos e ignora cualquier dígito después de un punto decimal. Si el valor es inferior a 1, Calc informa Err:504 (error en la lista de parámetros). Si el valor es mayor que el número de columnas en Base de datos, Calc informa un error #¡VALOR!

   - Al introducir el nombre literal de la cabecera de la columna desde la primera fila del intervalo Base de datos, entrecomillando el nombre de la cabecera. Por ejemplo, "Distancia a la escuela". Si la cadena no coincide con una de las cabeceras de columna del apartado Base de datos, Calc devuelve Err:504 (error en la lista de parámetros). También puede proporcionar una referencia a una celda arbitraria (fuera de los apartados Base de datos y Criterios de búsqueda) que contenga la cadena requerida.

   El argumento Campo de base de datos es opcional para las funciones DCONTAR y DCONTARA pero es necesario para las otras diez funciones de la base de datos.

3. argumento CriteriosDeBúsqueda

   Criterios de búsqueda especifica el rango de celdas que contienen los criterios de búsqueda. Al igual que Base de datos, su primera fila también son nombres de campo y las filas subsiguientes son condiciones para campos relacionados. Las áreas Base de datos y Criterios de búsqueda no necesitan estar adyacentes, ni siquiera en la misma hoja.

   Una referencia a una celda vacía se interpreta como el valor numérico 0.

   Una expresión coincidente puede ser:

   - Un número o valor lógico. Un contenido de celda correspondiente equivale al número o valor lógico.

   - A value beginning with a comparator (<, <=, =, >, >=, <>).

     En el caso de =, si el valor está vacío, coincide con las celdas vacías.

     En el caso de <>, si el valor está vacío, coincide con las celdas no vacías.

     For <>, if the value is not empty it matches any cell content except the value, including empty cells.

     Nota"=0" no coincide con las celdas vacías.

     For = and <>, if the value is not empty and can not be interpreted as a number type or one of its subtypes and the property Search criteria = and <> must apply to whole cells is checked, comparison is against the entire cell contents, if unchecked, comparison is against any subpart of the field that matches the criteria. For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes applies.

   - Other Text value. If the property Search criteria = and <> must apply to whole cells is true, the comparison is against the entire cell contents, if false, comparison is against any subpart of the field that matches the criteria. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

   Una forma de definir el intervalo de celdas es introducir la referencia de la celda superior izquierda, seguida de dos puntos (:), y luego la referencia de la celda inferior derecha. Por ejemplo, A13:B14. El intervalo de celdas también puede especificarse pasando el nombre de un intervalo con nombre definido o un intervalo de base de datos. Si el nombre no coincide con el de un intervalo definido, Calc emite un error #¿NOMBRE?

   El Err:504 (error en la lista de parámetros) también puede informarse como resultado de un argumento Criterio de búsqueda no válido

   El contenido del área Criterios de búsqueda se describe con más detalle en la siguiente sección.

### Definir criterios de búsqueda

El número de columnas ocupadas por el área Criterios de búsqueda no necesita ser el mismo ancho del área Base de datos. Todos los encabezados que aparecen en la primera fila deCriterios de búsqueda deben ser idénticos a los encabezados de la primera fila en la Base de datos. Sin embargo, no todos los encabezados en la Base de datos deben aparecer en la primera fila de Criterios de búsqueda, mientras que un encabezado en la Base de datos puede aparecer varias veces en la primera fila de Criterios de búsqueda.

Los criterios de búsqueda se ingresan en las celdas de la segunda y siguientes filas del área Criterios de búsqueda, debajo de la fila que contiene a los encabezados. Las celdas en blanco dentro del área Criterios de búsqueda deben ser ignorados.

Cree criterios en las celdas del área CriteriosDeBúsqueda mediante los operadores de comparación <, <=, =, <>, >= y >. = se asume si una celda no está vacía pero no comienza con un operador de comparación.

Si escribe varios criterios en una fila, están conectados por Y (AND). Si escribe varios criterios en diferentes filas, están conectados por O (OR).

Es posible crear criterios utilizando comodines; para ello, asegúrese de que esté activada la opción Permitir comodines en fórmulas del diálogo LibreOffice ▸ PreferenciasHerramientas ▸ Opciones ▸ LibreOffice Calc ▸ Calcular. Si la interoperatividad con Microsoft Excel es importante para su libro, esta opción debe estar activada.

Es posible crear criterios aun más sofisticados utilizando las expresiones regulares, siempre y cuando esté activada la opción Permitir expresiones regulares en las fórmulas en el diálogo LibreOffice ▸ PreferenciasHerramientas ▸ Opciones ▸ LibreOffice Calc ▸ Calcular.

Al utilizar funciones en las que uno o más argumentos son cadenas de criterios de búsqueda que representan una expresión regular, en primer lugar se intentará convertir los criterios de la cadena en números. Por ejemplo, «.0» se convertirá en 0.0 y así sucesivamente. Si el intento es fructuoso, la correspondencia no será por expresión regular, sino numérica. No obstante, si se cambia a una configuración regional en la cual el separador decimal no es el punto, pasará a valer la expresión regular. Para forzar la evaluación de la expresión regular en lugar de una expresión numérica, utilice una expresión que no pueda confundirse con un número, como por ejemplo «.\0» o «(?i).0».

Otra configuración que afecta la forma en que se manejan los criterios de búsqueda es la opción Los criterios de búsqueda = y <> deben aplicarse a celdas enteras en el LibreOffice - PreferenciasHerramientas - Opciones - LibreOffice Calc - cuadro de dialogo. Esta opción controla si los criterios de búsqueda que establece para las funciones de la base de datos deben hacer coincidir exactamente con toda la celda. Cuando la interoperatividad con Microsoft Excel es importante para su hoja de cálculo, esta opción debe estar habilitada.

### Ejemplos de uso de las funciones de base de datos

La tabla de base de datos siguiente es un ejemplo que demuestra cómo puede aprovechar las funciones de la categoría Base de datos. El intervalo de celdas A1:E10 contiene datos ficticios sobre las personas invitadas a la fiesta de cumpleaños de Juan. Se proporciona la información siguiente sobre cada invitado: nombre, grado escolar, edad en años, distancia a la escuela en metros y peso en kilogramos.

| A | B | C | D | E
1 | Nombre | Grado | Edad | Distancia | Peso
2 | Andrés | 3 | 9 | 150 | 40
3 | Beatriz | 4 | 10 | 1000 | 42
4 | Carlos | 3 | 10 | 300 | 51
5 | Daniel | 5 | 11 | 1200 | 48
6 | Eva | 2 | 8 | 650 | 33
7 | Franco | 2 | 7 | 300 | 42
8 | Greta | 1 | 7 | 200 | 36
9 | Henrique | 3 | 9 | 1200 | 44
10 | Irene | 2 | 8 | 1000 | 42
11 |  |  |  |  |

Los seis ejemplos siguientes utilizan la tabla de la base de datos anterior en combinación con distintas áreas de criterios de búsqueda.

#### Ejemplo 1

| A | B | C | D | E
12 | Nombre | Grado | Edad | Distancia | Peso
13 |  |  |  | >600 |
14 |  |  |  |  |

Como en este sencillo ejemplo, a veces es recomendable (pero no esencial) colocar el área de criterios de búsqueda directamente debajo de la tabla de la base de datos, con las columnas de las dos áreas alineadas verticalmente. Las entradas en blanco en el área de criterios de búsqueda se ignoran. Con la tabla de base de datos de ejemplo anterior y esta área de criterios de búsqueda, inserte la fórmula =BDCONTAR(A1:E10;;A12:E14) en una celda vacía en otra parte de la hoja para contar cuántos de los invitados de Juan viajan más de 600 metros a la escuela. Devolverá el valor 5 (Beatriz, Daniel, Eva, Henrique e Irene).

Observe también que la fórmula =BDCONTAR(A1:E10;;D12:D13) devuelve el mismo valor exacto, lo que demuestra que solo es necesario que el área de criterios de búsqueda contenga los títulos de columnas pertinentes.

#### Ejemplo 2

| A | B | C | D | E
12 |  | Edad | Grado |  |
13 |  | >7 | 2 |  |
14 |  |  |  |  |

En este ejemplo, el área de criterios de búsqueda contiene solo dos encabezados y estos no están alineados verticalmente con los encabezados correspondientes en la tabla de la base de datos del ejemplo. Como hay dos condiciones en la misma fila, estas están conectadas por Y (AND). Con la tabla de base de datos de ejemplo anterior y esta área de criterios de búsqueda, inserte la fórmula =BDCONTAR(A1:E10;;B12:C13) en una celda vacía en otra parte de la hoja para contar cuántos de los invitados de Juan están en el grado 2 y son mayores de 7 años. Devolverá el valor 2 (Eva e Irene).

#### Ejemplo 3

| A | B | C | D | E
12 |  | Edad |  |  |
13 |  | 9 |  |  |
14 |  | 10 |  |  |

En este ejemplo, el área de criterios de búsqueda contiene solo un título. Dado que hay dos condiciones en filas consecutivas, estas están conectadas por O (OR). Con la tabla de la base de datos de ejemplo anterior y esta área de criterios de búsqueda, inserte la fórmula =BDCONTAR(A1:E10;;B12:B14) en una celda vacía en otra parte de la hoja para contar cuántos de los invitados de Juan tienen 9 o 10 años. Se devolverá el valor 4 (contando a Andrés, Beatriz, Carlos y Henrique).

#### Ejemplo 4

| A | B | C | D | E
12 |  | Edad | Edad |  |
13 |  | >=8 | <=10 |  |
14 |  |  |  |  |

En este ejemplo, el área de criterios de búsqueda contiene dos ocurrencias del mismo título. Como hay dos condiciones en la misma fila, estas están conectadas por Y (AND). Con la tabla de la base de datos de ejemplo anterior y esta área de criterios de búsqueda, inserte la fórmula =BDCONTAR(A1:E10;;B12:C13) en una celda vacía en otra parte de la hoja para contar cuántos de los invitados de Juan tienen entre 8 y 10 años (inclusive). Devolverá el valor 6 (Andrés, Beatriz, Carlos, Eva, Henrique e Irene).

#### Ejemplo 5

| A | B | C | D | E
12 | Nombre |  |  |  |
13 | F* |  |  |  |
14 |  |  |  |  |

Este sencillo ejemplo muestra el uso de comodines. Para que este ejemplo funcione como se pretende, seleccione activar los comodines en LibreOffice - PreferenciasHerramientas - Opciones - LibreOffice Calc - Calcular. Con la tabla de base de datos del ejemplo anterior y esta área de criterios de búsqueda, inserte la fórmula =DCOUNT(A1:E10;;A12:A13)en una celda vacía en cualquier lugar de la hoja para contar cuántos de los huéspedes de Joe tienen nombres que empiezan por la letra "F". Se devuelve el valor 1 (contando a Frank).

#### Ejemplo 6

| A | B | C | D | E
12 | Nombre |  |  |  |
13 | [ABC].* |  |  |  |
14 |  |  |  |  |

Este sencillo ejemplo muestra el uso de expresiones regulares. Para que este ejemplo funcione como se pretende, seleccione activar las expresiones regulares enLibreOffice ▸ PreferenciasHerramientas ▸ Opciones ▸ LibreOffice Calc ▸ Calcular. Con la tabla de base de datos de ejemplo anterior y esta área de criterios de búsqueda, inserte la fórmula =BDCONTAR(A1:E10;;A12:A13) en una celda vacía en cualquier lugar de la hoja para contar cuántos de las visitas de Juan tienen nombres que empiezan por las letras «A», «B» o «C». Se devuelve el valor 3 (contando a Andrés, Beatriz y Carlos).

## BDCONTAR

BDCONTAR cuenta el número de celdas (campos) de la columna especificada que contienen valores numéricos, para todas las filas (registros de la base de datos) que coinciden con los criterios de búsqueda especificados. Sin embargo, si no se especifica ninguna columna, BDCONTAR devuelve el recuento de todos los registros que coinciden con los criterios de búsqueda especificados, independientemente de su contenido.

#### Sintaxis

BDCONTAR(BaseDeDatos; [CampoDeBaseDeDatos]; CriteriosDeBúsqueda)

#### Ejemplo

La tabla de la base de datos de ejemplo que proporciona información sobre los invitados a la fiesta de cumpleaños de Juan (descrita anteriormente) debería ocupar las celdas A1:E10. El contenido de las celdas A12:E12 debe ser idéntico a las etiquetas de cabecera de la tabla de la base de datos en las celdas A1:E1. Asegúrese de que las celdas A13:E13 estén en blanco, a excepción de la celda D13 que debe contener «>600» (este criterio de búsqueda coincidirá con los registros en la tabla de la base de datos que tengan un valor superior a 600 en la columna Distancia).

Inserte la fórmula =BDCONTAR(A1:E10;; A12:E13) en una celda vacía en otra parte de la hoja para calcular cuántos de los invitados a la fiesta de Juan viajan más de 600 metros a la escuela. Devolverá el valor 5.

Se obtiene el mismo resultado si usa la fórmula =BDCONTAR(A1:E10; "Distancia"; A12:E13), porque todas las entradas en la columna distancia son numéricas. Sin embargo, si se usa la fórmula =BDCONTAR(A1:E10; "Nombre"; A12:E13), devuelve el valor 0 porque todas las entradas en la columna nombre no son numéricas.

## BDCONTARA

BDCONTARA cuenta el número de celdas (campos) de la columna especificada que no están en blanco, para todas las filas (registros de la base de datos) que coinciden con los criterios de búsqueda especificados. Las celdas en blanco de la columna especificada no se cuentan. Sin embargo, si no se especifica ninguna columna, BDCONTARA hace el recuento de todos los registros que coinciden con los criterios de búsqueda especificados, independientemente de su contenido.

#### Sintaxis

BDCONTARA(BaseDeDatos;[CampoDeBaseDeDatos];CriteriosDeBúsqueda)

#### Ejemplo

La tabla de la base de datos de ejemplo que proporciona información sobre los invitados a la fiesta de cumpleaños de Juan (descrita anteriormente) debería ocupar las celdas A1:E10. El contenido de las celdas A12:E12 debe ser idéntico a las etiquetas de cabecera de la tabla de la base de datos en las celdas A1:E1. Asegúrese de que las celdas A13:E13 estén en blanco, a excepción de la celda D13 que debe contener «>600» (este criterio de búsqueda coincidirá con los registros en la tabla de la base de datos que tengan un valor superior a 600 en la columna Distancia).

Inserte la fórmula =BDCONTARA(A1:E10;; A12:E13) en una celda vacía en otra parte de la hoja para calcular cuántos de los invitados a la fiesta de Juan viajan más de 600 metros a la escuela. Devolverá el valor 5.

Se obtiene el mismo resultado si utiliza la fórmula =BDCONTARA(A1:E10; "Distancia"; A12:E13) o la fórmula =BDCONTARA(A1:E10; "Nombre"; A12 :E13). El último caso refleja que, a diferencia de BDCONTAR, BDCONTARA cuenta valores numéricos y alfanuméricos en la columna indicada por el argumento CampoDeBaseDeDatos.

## BDDESVEST

BDDESVEST calcula la desviación típica de la muestra en función de los valores numéricos en las celdas (campos) de la columna especificada, para todas las filas (registros de la base de datos) que coinciden con los criterios de búsqueda especificados. Los valores numéricos se ignoran.

Devuelve un error #¡NUM! si un registro coincide exactamente con los criterios de búsqueda especificados, o si solo hay un valor numérico en las celdas de la columna especificada para los registros coincidentes.

Devuelve 0 si no se produce ninguna correspondencia o si no hay valores numéricos en las celdas de la columna especificada para los registros correspondientes.

#### Sintaxis

BDDSTDEV(Base de Datos; Campo Base de Datos; Búsqueda por Criterios)

#### Ejemplo

La tabla de base de datos del ejemplo que da información sobre los invitados a la fiesta de cumpleaños de Joe (descrita anteriormente) debe ocupar las celdas A1:E10. El contenido de las celdas A12:E12 debe ser idéntico al de las etiquetas de cabecera de la tabla de la base de datos en las celdas A1:E1. Debe asegurarse que las celdas A13:D13 estén en blanco y que la celda E13 contenga ">0" (este criterio de búsqueda pretende hacer coincidir con todos los registros de la tabla de la base de datos).

Inserta la fórmula =BDDESVEST(A1:E10; "Peso"; A12:E13) en una celda vacía de otro lugar de la hoja para calcular la desviación estándar muestral de los pesos en kg de los invitados a la fiesta de Joe. Nos devolverá el valor 5,5.

## BDDESVESTP

BDDESVESTP calcula la desviación estándar de la población basándose en los valores numéricos de las celdas (campos) de la columna especificada, para todas las filas (registros de la base de datos) que coincidan con los criterios de búsqueda especificados. Los valores no numéricos se ignoran.

Devuelve el error #¡NUM! si no se corresponde ningún registro con los criterios de búsqueda dados o si no hay valores numéricos en las celdas de la columna especificada para los registros correspondientes.

#### Sintaxis

BDDESVESTP(Base de Datos; Campo Base de Datos; Búsqueda por Criterios)

#### Ejemplo

La tabla de base de datos del ejemplo que da información sobre los invitados a la fiesta de cumpleaños de Joe (descrita anteriormente) debe ocupar las celdas A1:E10. El contenido de las celdas A12:E12 debe ser idéntico al de las etiquetas de cabecera de la tabla de la base de datos en las celdas A1:E1. Debe asegurarse de que las celdas A13:D13 estén en blanco y que la celda E13 contenga ">0" (este criterio de búsqueda pretende hacer coincidir con todos los registros de la tabla de la base de datos).

Inserte la fórmula =BDESVESTP(A1:E10; "Peso"; A12:E13) en una celda vacía en otra parte de la hoja para calcular la desviación típica de población de los pesos en kilogramos de los invitados a la fiesta de Juan. Devolverá el valor 5,18545.

## BDEXTRAER

BDEXTRAER devuelve el contenido de la celda (campo) de la columna especificada, para la única fila (registro de la base de datos) que coincide con los criterios de búsqueda especificados.

Calc emite el Err:502 (argumento no válido) si se encuentran varias coincidencias, o bien, un error #¡VALOR! (tipo de datos incorrecto) si no se encuentran coincidencias. También se devuelve un error #¡VALOR! si se encuentra una sola coincidencia pero la celda correspondiente está vacía.

#### Sintaxis

BDEXTRAER(BaseDeDatos; CampoDeBaseDeDatos; CriteriosDeBúsqueda)

#### Ejemplo

La tabla de base de datos de ejemplo que da información sobre los invitados a la fiesta de cumpleaños de Joe (descrita anteriormente) debe ocupar las celdas A1:E10. El contenido de las celdas A12:E12 debe ser idéntico al de las etiquetas de cabecera de la tabla de la base de datos en las celdas A1:E1. Asegúrese de que las celdas A13:E13 estén en blanco, excepto la celda C13 que debe contener "11" (este criterio de búsqueda coincidirá con los registros de la tabla de la base de datos que tengan un valor de 11 en la columna edad).

Inserta la fórmula =BDEXTRAER(A1:E10; "Nombre"; A12:E13) en una celda vacía en otro lugar de la hoja para encontrar el nombre del invitado a la fiesta de Joe que tiene 11 años. Nos devolverá el nombre de Daniel.

Si cambia el valor de la celda C13 a «10», la fórmula =BDEXTRAER(A1:E10; "Nombre"; A12:E13) devuelve un error de argumento no válido (Err:502). Refleja que varios registros coinciden con el criterio especificado (tanto Beatriz como Carlos tienen 10 años).

## BDMAX

BDMAX calcula el valor máximo en todas las celdas (campos) de la columna especificada que contienen valores numéricos, para todas las filas (registros de la base de datos) que coinciden con los criterios de búsqueda especificados. No se incluyen las celdas en blanco ni las que contienen caracteres no numéricos.

Devuelve 0 si no se encuentran coincidencias o si no hay valores numéricos distintos de cero en las celdas de la columna especificada para los registros coincidentes.

#### Sintaxis

BDMAX(BaseDeDatos; CampoDeBaseDeDatos; CriteriosDeBúsqueda)

#### Ejemplo

La tabla de base de datos del ejemplo que da información sobre los invitados a la fiesta de cumpleaños de Joe (descrita anteriormente) debe ocupar las celdas A1:E10. El contenido de las celdas A12:E12 debe ser idéntico al de las etiquetas de cabecera de la tabla de la base de datos en las celdas A1:E1. Asegúrese de que las celdas A13:E13 estén en blanco, excepto la celda D13, que debe contener ">0" (este criterio de búsqueda pretende coincidir con todos los registros de la tabla de la base de datos).

Inserte la fórmula =BDMAX(A1:E10; "Distancia"; A12:E13) en una celda vacía en otra parte de la hoja para encontrar la distancia máxima en metros que recorre cualquiera de los invitados a la fiesta de Juan hasta a la escuela. Devolverá el valor 1200.

## BDMIN

BDMIN calcula el valor mínimo en todas las celdas (campos) de la columna especificada que contienen valores numéricos, para todas las filas (registros de la base de datos) que coinciden con los criterios de búsqueda especificados. No se incluyen las celdas en blanco ni las que contienen caracteres no numéricos.

Devuelve 0 si no se encuentran coincidencias o si no hay valores numéricos distintos de cero en las celdas de la columna especificada para los registros coincidentes.

#### Sintaxis

BDMIN(BaseDeDatos; CampoDeBaseDeDatos; CriteriosDeBúsqueda)

#### Ejemplo

La tabla de base de datos del ejemplo que da información sobre los invitados a la fiesta de cumpleaños de Joe (descrita anteriormente) debe ocupar las celdas A1:E10. El contenido de las celdas A12:E12 debe ser idéntico al de las etiquetas de cabecera de la tabla de la base de datos en las celdas A1:E1. Asegúrese de que las celdas A13:E13 estén en blanco, excepto la celda D13, que debe contener ">0" (este criterio de búsqueda pretende coincidir con todos los registros de la tabla de la base de datos).

Inserta la fórmula =BDMIN(A1:E10; "Distancia"; A12:E13) en una celda vacía de otro lugar de la hoja para encontrar la distancia mínima en metros que recorre cualquiera de los invitados a la fiesta de Joe hasta la escuela. Nos devolverá el valor 150.

## BDPRODUCTO

BDPRODUCTO calcula el producto de todos los valores numéricos de las celdas (campos) de la columna especificada, para todas las filas (registros de la base de datos) que coinciden con los criterios de búsqueda especificados. No se incluyen las celdas en blanco ni las que contienen caracteres no numéricos.

Devuelve 0 si no se produce ninguna correspondencia o si no hay valores numéricos en las celdas de la columna especificada para los registros correspondientes.

#### Sintaxis

BDPRODUCTO(BaseDeDatos; CampoBaseDeDatos; CriteriosDeBúsqueda)

#### Ejemplo

La tabla de base de datos del ejemplo que da información sobre los invitados a la fiesta de cumpleaños de Joe (descrita anteriormente) debe ocupar las celdas A1:E10. El contenido de las celdas A12:E12 debe ser idéntico al de las etiquetas de cabecera de la tabla de la base de datos en las celdas A1:E1. Asegúrese de que las celdas A13:E13 estén en blanco, excepto la celda C13, que debe contener ">0" (este criterio de búsqueda pretende hacer coincidir con todos los registros de la tabla de la base de datos).

Inserte la fórmula =BDPRODUCTO(A1:E10; "Edad"; A12:E13) en una celda vacía en otra parte de la hoja para calcular el producto de las edades en años de los invitados a la fiesta de Juan. Devolverá el valor 279417600.

## BDPROMEDIO

BDPROMEDIO calcula la media de los valores numéricos de las celdas (campos) de la columna especificada, para todas las filas (registros de la base de datos) que coinciden con los criterios de búsqueda especificados. Los valores no numéricos de esas celdas deben ser ignorados.

Devuelve un error #¡DIV/0! si ningún registro coincide con los criterios de búsqueda especificados, o si no hay valores numéricos en las celdas de la columna especificada para los registros coincidentes.

#### Sintaxis

BDPROMEDIO(Base de datos; Campo de base de datos; Criterios de búsqueda)

#### Ejemplo

La tabla de la base de datos de ejemplo que proporciona información sobre los invitados a la fiesta de cumpleaños de Juan (descrita anteriormente) debe situarse en las celdas A1:E10. El contenido de las celdas A12:E12 debe ser idéntico a las etiquetas de cabecera de la tabla de la base de datos en las celdas A1:E1. Asegúrese de que las celdas A13:E13 estén en blanco, a excepción de la celda D13 que debe contener «>0» (este criterio de búsqueda tiene como objetivo hacer coincidir todos los registros en la tabla de la base de datos).

Introduzca la fórmula =BDPROMEDIO(A1:E10; "Distancia"; A12:E13) en una celda vacía de otro lugar de la hoja para calcular la distancia media en metros recorrida hasta la escuela por los invitados a la fiesta de Joe. Se obtendrá el valor 666,67.

## BDSUMA

BDSUMA calcula la suma de todos los valores numéricos en las celdas (campos) de la columna especificada, para todas las filas (registros de la base de datos) que coinciden con los criterios de búsqueda especificados. Las celdas en blanco o celdas que contienen caracteres no numéricos no están incluidas.

Devuelve 0 si no se produce ninguna correspondencia o si no hay valores numéricos en las celdas de la columna especificada para los registros correspondientes.

#### Sintaxis

BDSUM(Base de Datos; Campo Base de Datos; Búsqueda por Criterios)

#### Ejemplo

La tabla de base de datos del ejemplo que da la información sobre los invitados a la fiesta de cumpleaños de Joe (descrita anteriormente) debe ocupar las celdas A1:E10. El contenido de las celdas A12:E12 debe ser idéntico al de las etiquetas de cabecera de la tabla de la base de datos en las celdas A1:E1. Asegúrese de que las celdas A13:E13 estén en blanco, excepto la celda D13, que debe contener ">0" (este criterio de búsqueda pretende hacer coincidir con todos los registros de la tabla de la base de datos).

Inserte la fórmula =BDSUMA(A1:E10; "Distancia"; A12:E13) en una celda vacía en otra parte de la hoja para encontrar la distancia total en metros que todos los invitados a la fiesta de Juan viajan a la escuela. Devolverá el valor 6000.

## BDVAR

BDVAR calcula la varianza de la muestra en función de los valores numéricos en las celdas (campos) de la columna especificada, para todas las filas (registros de la base de datos) que coinciden con los criterios de búsqueda especificados. Los valores no numéricos son ignorados.

Devuelve un error #¡NUM! si un registro coincide exactamente con los criterios de búsqueda especificados, o si solo hay un valor numérico en las celdas de la columna especificada para los registros coincidentes.

Devuelve 0 si no se produce ninguna correspondencia o si no hay valores numéricos en las celdas de la columna especificada para los registros correspondientes.

#### Sintaxis

BDVAR(Base de Datos; Campo de la Base de Datos; Criterios de búsqueda)

#### Ejemplo

La tabla de base de datos del ejemplo que da información sobre los invitados a la fiesta de cumpleaños de Joe (descrita anteriormente) debe ocupar las celdas A1:E10. El contenido de las celdas A12:E12 debe ser idéntico al de las etiquetas de cabecera de la tabla de la base de datos en las celdas A1:E1. Debe asegúrese de que las celdas A13:E13 estén en blanco, excepto la celda D13, que debe contener ">0" (este criterio de búsqueda pretende hacer coincidir con todos los registros de la tabla de la base de datos).

Inserta la fórmula =BDVAR(A1:E10; "Distancia"; A12:E13) en una celda vacía de otro lugar de la hoja para encontrar la varianza muestral de las distancias en metros que los invitados a la fiesta de Joe recorren hasta la escuela. Nos devolverá el valor 193125.

## BDVARP

BDVARP calcula la variación de la población según los valores numéricos en las celdas (campos) de la columna especificada, para todas las filas (registros de la base de datos) que coinciden con los criterios de búsqueda especificados. Los valores no numéricos son ignorados.

Devuelve el error #¡NUM! si no se corresponde ningún registro con los criterios de búsqueda dados o si no hay valores numéricos en las celdas de la columna especificada para los registros correspondientes.

#### Sintaxis

BDVARP(Base de Datos; Campo de la Base de Datos; Criterios de búsqueda)

#### Ejemplo

La tabla de base de datos del ejemplo que da información sobre los invitados a la fiesta de cumpleaños de Joe (descrita anteriormente) debe ocupar las celdas A1:E10. El contenido de las celdas A12:E12 debe ser idéntico al de las etiquetas de cabecera de la tabla de la base de datos en las celdas A1:E1. Asegúrese de que las celdas A13:E13 estén en blanco, excepto la celda D13, que debe contener ">0" (este criterio de búsqueda pretende hacer coincidir con todos los registros de la tabla de la base de datos).

Inserta la fórmula =BDVARP(A1:E10; "Distancia"; A12:E13) en una celda vacía en otra parte de la hoja para encontrar la varianza poblacional de las distancias en metros que los invitados a la fiesta de Joe recorren hasta la escuela. Obtenemos el valor 171666,67.

Temas relacionados

Funciones por categoría

Definir un intervalo de base de datos

Funciones de base de datos

Definir intervalo

Database Table Reference

¡Necesitamos su ayuda!