Inhoud

# Instructie Property

Een eigenschap, ook property, veld of attribuut genoemd, beschrijft een bepaald object of wat informatie. Met een property kan toegang tot de gegevens worden verkregen. Het is gebruikelijk om instructies toe te voegen om een eigenschap te lezen of een waarde te geven. De codehiervan kan een simpele toekenning zijn of een complexe routine die afhankelijk is van de context. Door deze instructies Get, Let en Set te gebruiken, kan het consistent zijn van de gegevens worden afgedwongen.

Bij deze instructie is het verplicht dat Option Compatible geplaatst is in de module voor het uitvoerbare gedeelte van de code.

### Syntaxis:

             [Private | Public] Property Get name[char | As typename]
             End Property

             [Private | Public] Property [Let | Set] name[char] [([Optional [ByRef | ByVal]]value[char | As typename])] [As typename]
             End Property

### Parameters:

name: De naam van de eigenschap.

argument: De waarde die wordt doorgegeven aan de routine om de Property een waarde te geven.

De waarde van een Property wordt meestal met één argument doorgegeven.

##### fragment argument

          {[Optional [ByRef|ByVal]]|ParamArray} argument {{As typename|char}[ = expression]|[()]As Variant}

##### Parameters

Optioneel: Het argument is niet verplicht.

ByRef: Het argument wordt op referentie doorgegeven. ByRef is de standaardwaarde.

ByVal: De waarde wordt meegegeven. Deze waarde kan door de aangeroepen routine worden gewijzigd.

char: Het teken voor de declaratie van het type.

typename: Naam van het primitieve datatype. U kunt ook types specificeren die in bibliotheken en modules zijn gedefinieerd.

= expression: Specificeer een standaardwaarde die overeenkomt met het type. Als u een standaardwaarde voor een argument specificeert, dan is het logisch dat het argument optioneel is.

ParamArray: Gebruik ParamArray als het aantal parameters niet bekend is. Een voorbeeld hiervan is een door de gebruiker gedefinieerde functie in Calc. Als het argument ParamArray gebruikt wordt dan zou het altijd het laatste genoemde argument van de routine moeten zijn.

Bij het gebruik van ParamArray of = expression is het verplicht dat Option Compatible wordt gebruikt in de code van de module voor het uitvoerbare gedeelte van de code.

Bij het gebruik van Option VBASupport 1, Optional worden argumenten zonder standaardwaarde (= expression) geïnitialiseerd op grond van hun gegevenstype, m.u.v het type Variant.

##### fragment typename

          {Boolean|Byte|Currency|Date|Double|Integer|Long|Object|Single|String|Variant}

##### fragment char

          { % | & | ! | # | $ | @ }

## Voorbeelden

          Option Compatible
          Sub Main
              ProductName = "Office"
              Print ProductName ' uitvoer: "LibreOffice"
          End Sub

          Private _office As String
          Property Get ProductName As String
              ProductName = _office
          End Property
          Property Let ProductName(value As String)
              _office = "Libre"& value
          End Property

Als er geen property Let of Set is, kan met Get het beveiligde gegeven wordt gelezen, de waarde kan dan niet per ongeluk door een andere module worden gewijzigd.

          Option Compatible
          Public Property Get PathDelimiter As String ' Deze variabele kan alleen worden gelezen
              Static this As String
              If this = "" Then : Select Case GetGuiType()
                  Case 1 : this = ";" ' Windows
                  Case 4 : this = ":" ' Linux of macOS
                  Case Else : Error 423 ' Eigenschap od methode niet gedefinieerd : PathDelimiter
              End Select : End If
              PathDelimiter = this
          End Property ' alleen-lezen veld PathDelimiter

          Sub Main
              PathDelimiter = "een zin" ' doet niks
          End Sub

Gebruik Let of Set voor het verwerken van UNO-services of objectklassen:

          Option Compatible
          Sub Main
              'Set anObject = CreateUnoService( "com.sun.star.frame.Desktop" )
              anObject = CreateUnoService( "com.sun.star.frame.Desktop" )
              Print anObject.SupportedServiceNames(0) ' displays "com.sun.star.frame.Frame"
          End Sub

          Property Get anObject As Object
              Set anObject = _obj
          End Property

          Private _obj As Object

          'Property Set anObject(value As Object)
              'Set _obj = value.CurrentFrame
          'End Property
          Property Let anObject(value As Object)
              Set _obj = value.CurrentFrame
          End Property

Verwante onderwerpen

Grondbeginselen subroutines

Procedures, Functies of Eigenschappen gebruiken

Instructie Function

Instructie Sub

Instructies End, Exit

Instructie Option ClassModule

Instructie Option Compatible

Help ons, alstublieft!